BEGIN {
    home = "http://www.complang.tuwien.ac.at/";
    site = home;
    date = strftime("%a, %d %b %Y %T %z");
    datefound = 0;
    timefound = 0;
    description = ""
    title= "";
    pretitle ="";

    rsstitle = "";
    rssdescr = "";
}

($1 == "%encoding"){
    if(NF != 2 ){
        print FILENAME " (line " FNR "): WARNING: %encoding entry with missing parameters" >"/dev/stderr";
        next;
    }
    else{
        encoding = $2;
    }
}
($1 == "%rsstitle"){
    if(NF < 2 ){
        print FILENAME " (line " FNR "): WARNING: %rsstitle entry with missing parameters" >"/dev/stderr";
        next;
    }
    else{
        rsstitle = substr($0, 11);
    }
}
($1 == "%rsslink"){
    if(NF < 2 ){
        print FILENAME " (line " FNR "): WARNING: %rsslink entry with missing parameters" >"/dev/stderr";
        next;
    }
    else{
        rsslink = substr($0, 10);
    }
}
($1 == "%rsspage"){
    if(NF < 2 ){
        print FILENAME " (line " FNR "): WARNING: %rsspage entry with missing parameters" >"/dev/stderr";
        next;
    }
    else{
        rsspage = substr($0, 10);
    }
}
($1 == "%rssdescr"){
    if(NF < 2 ){
        print FILENAME " (line " FNR "): WARNING: %rssdesc entry with missing parameters" >"/dev/stderr";
        next;
    }
    else{
        rssdescr = substr($0, 11);
    }
}

($1 == "%news") && (output == 0) {
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %news missing an argument" >"/dev/stderr";
    }
    output = 1;
    print "<item>"; 
    print "<guid isPermaLink=\"false\">" $2 "</guid>";

    next;
}
($1 == "%title") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %title missing an argument" >"/dev/stderr";
    }
    title = substr($0, 8);
    next;
}
($1 == "%pretitle") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %pretitle missing an argument" >"/dev/stderr";
    }
    pretitle = substr($0, 11);
    next;
}

($1 == "%url") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %url missing an argument" >"/dev/stderr";
    }
    url = substr($0, 6);
    next;
}

($1 == "%date") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %date missing an argument" >"/dev/stderr";
    }
    pubDate = substr($0, 7)
    datefound = 1;
    next;
}
($1 == "%time") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %time missing an argument" >"/dev/stderr";
    }
    pubTime = substr($0, 7)
    timefound = 1;
    next;
}

($1 == "%place") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %place missing an argument" >"/dev/stderr";
    }
    place = substr($0, 8);
    placefound = 1;
    next;
}
($1 == "%pubdate") && (output == 1){
    if (NF < 2) {
        print FILENAME " (line " FNR "): WARNING: %pubdate missing an argument" >"/dev/stderr";
    }
    pubdate_rss = substr($0, 10);

    next;
}
($1 == "%endnews") && (output == 1){
# print description
# escape html first
    output = 0;

    gsub(/&/, "\\&amp;", description);
    gsub(/</, "\\&lt;", description);
    print "<description>";
    print description;

    description = "";

    if (timefound == 1 && datefound == 1 && placefound == 1) {
        gsub(/&/, "\\&amp;", pubDate);
        gsub(/</, "\\&lt;", pubDate);
        gsub(/&/, "\\&amp;", pubTime);
        gsub(/</, "\\&lt;", pubTime);
        gsub(/&/, "\\&amp;", place);
        gsub(/</, "\\&lt;", place);

        print "&lt;DL>"
        print "&lt;DT>Datum:&lt;/DT>&lt;DD>" pubDate "&lt;/DD>"
        print "&lt;DT>Uhrzeit:&lt;/DT>&lt;DD>" pubTime "&lt;/DD>"
        print "&lt;DT>Ort:&lt;/DT>&lt;DD>"place"&lt;/DD>"
        print "&lt;/DL>"
        timefound = 0;
        datefound = 0;
        placefound = 0;
        pubDate = "";
        pubTime = "";
        place = "";
    }

    print "</description>";
    temp_title = "";
    if (pretitle != "" ){
        print "<title>" pretitle ": " title "</title>";
    }
    else{
        print "<title>" title "</title>";
    }

    if (pubdate_rss != "") {
        print "<pubDate>" pubdate_rss "</pubDate>";
    }

    if (url != ""){
        print "<link>" url "</link>";
        url = ""
    }
    else {
       print "<link>" home "" rsspage "</link>"; 
    }

    print "</item>"

    next;
}

(output == 1){
    description = description "\n" $0
    next;
}

($1 == "%content") && (output == 0) {
    if (encoding == "") {
        # encoding must be set before! 
        exit EXIT_FAILURE;
    }
    print "<?xml version=\"1.0\" encoding=\"" encoding "\" ?>";
    print "<rss version=\"2.0\" xmlns:atom=\"http://www.w3.org/2005/Atom\">";
    print "<channel>";
    print "<atom:link href=\"" home "" rsslink "\" rel=\"self\" type=\"application/rss+xml\" />"
    
    print "<title>" rsstitle "</title>";
    print "<description>" rssdescr "</description>";
    print "<link>" site "</link>";
    print "<lastBuildDate>" date "</lastBuildDate>";
    print "<pubDate>" date  "</pubDate>";
    print "<ttl>1800</ttl>";

    contentfound = 1;

    next;
}
END {
# only if the xml header was printed, also print the footer
    if (contentfound == 1){
        print "</channel>";
        print "</rss>";
    }
}