BEGIN {
    if (encoding == "") {
	encoding = "ISO-8859-1";
    }
    rsslink = "";
    home = "http://www.complang.tuwien.ac.at/";
    site = home;
    css = "complang.css";
    favicon = "favicon.ico";
    start = "index";
    if (lang == "en")
	start = "english";
    output = 0;
    thislevel = 0;
    outer = "";
    menu = "";
    statement = "";
    Astart = "<A href=\"";
    Atitle = "\" title=\""
    Amid = "\">";
    Aend = "</A>";
    indent[0] = "";
    indent[1] = "  ";
    indent[2] = "      ";
    indent[3] = "          ";
    indent[4] = "              ";
    indent[5] = "                  ";
    indent[6] = "                      ";
    alang["en"] = "also in German";
    alang["de"] = "also in English";
    sorry["en"] = "nur englisch";
    sorry["de"] = "only in German";
    alang2["en"] = "German";
    alang2["de"] = "English";
    startt["en"] = "start page";
    startt["de"] = "Startseite";
    otherlang["de"] = "en";
    otherlang["en"] = "de";
    langcare = 0;
    lastup = "";
    fisite["de"] = "http://www.informatik.tuwien.ac.at/";
    fisite["en"] = "http://www.informatik.tuwien.ac.at/english/";
    fititle["de"] = "Fakult&auml;t f&uuml;r Informatik";
    fititle["en"] = "Faculty of Informatics";
    tutitle["de"] = "Technische Universit&auml;t Wien";
    tutitle["en"] = "Vienna University of Technology";
    hometitle["de"] = "Die Complang-Gruppe";
    hometitle["en"] = "The Complang Group";
    upper["de"] = "h&ouml;here&nbsp;Ebene";
    upper["en"] = "Upper&nbsp;Level";
    uppertitle["de"] = "Sitemap auf der h&ouml;heren Ebene";
    uppertitle["en"] = "Sitemap at the Upper Level";
    thispage["de"] = "Kurzbezeichnung der aktuellen Seite";
    thispage["en"] = "Short Name of Current Page";
    addr["de"] = "  <A href=\"#top\" title=\"Anfang dieser Seite\">Anfang</A> |\n  <A href=\"http://validator.w3.org/check/referer\" title=\"&Uuml;berpr&uuml;fung dieser Seite auf syntaktische Korrektheit\">HTML 4.01</A> |\n  <A href=\"https://www.tuwien.ac.at/dle/datenschutz_und_dokumentenmanagement/datenschutz/unterstuetzung_und_services/ds_erklaerung_websites/\" title=\"Datenschutzerkl&auml;rung der TU Wien\">Datenschutzerkl&auml;rung</A> |\n  letzte &Auml;nderung: " date " (" gsign ")";
    addr["en"] = "  <A href=\"#top\" title=\"Top of this Page\">top</A> |\n  <A href=\"http://validator.w3.org/check/referer\" title=\"Syntactic Correctness Check of this Page\">HTML 4.01</A> |\n  <A href=\"https://www.tuwien.ac.at/dle/datenschutz_und_dokumentenmanagement/datenschutz/unterstuetzung_und_services/ds_erklaerung_websites/\" title=\"Datenschutzerkl&auml;rung der TU Wien\">Datenschutzerkl&auml;rung</A> |\n  last update: " date " (" esign ")";
    further["de"] = "Seiten und Dateien, die nicht im linken Men&uuml; aufscheinen:";
    further["en"] = "Resources not occurring in the menue on the left hand side:";
    preferences["de"] = "<H4>Einstellungen:</H4>\nDiese Web-Seiten verwenden Einstellungen Ihres Browsers. Vor allem\nSchriftgr&ouml;&szlig;en und Unterstreichungen von Links k&ouml;nnen Sie\ndurch Einstellungen in Ihrem Browser &auml;ndern. Die Breite der Seiten\n&auml;ndert sich mit der Schriftgr&ouml;&szlig;e.";
    preferences["en"] = "<H4>Preferences:</H4>\nThese web pages use preferences set in your browser. Especially font sizes\nand underlining of links depend on your browser settings. Page widths\nchange with font sizes.";
}
function noindex(ind) {
    if (ind == "index")
	return home;
    else
	return ind;
}
($1 == "%encoding"){
    if(NF != 2 ){
        print FILENAME " (line " FNR "): WARNING: %encoding entry with missing parameters" >"/dev/stderr";
        next;
    }
    else{
        encoding = $2;
    }
}
($1 == "%altlng") {
    if (NF < 3)
	print FILENAME " (line " FNR "): WARNING: %altlang has less than 2 arguments" >"/dev/stderr";
    if (altlang[$2] != "" && altlang[$2] != $3)
	print FILENAME " (line " FNR "): WARNING: " $2 " already has " altlang[$2] " as page name of alternative language; overridden by " $3 >"/dev/stderr";
    if (altlang[$3] != "" && altlang[$3] != $2)
	print FILENAME " (line " FNR "): WARNING: " $3 " already has " altlang[$3] " as page name of alternative language; overridden by " $2 >"/dev/stderr";
    altlang[$2] = $3;
    altlang[$3] = $2;
    next;
}
($1 == "%map") {
    if (thislevel < 0)
	print FILENAME " (line " FNR "): WARNING: %map follows %nomap" >"/dev/stderr";
    if (NF < 6)
	print FILENAME " (line " FNR "): WARNING: %map has less than 5 arguments" >"/dev/stderr";
    name = $2;
    thislang = $3;
    if (thislang != "de" && thislang != "en")
	print FILENAME " (line " FNR "): WARNING: language \"" thislang "\" not supported" >"/dev/stderr";
    pred = $4;
    stitle = $5;
    brackets = 0;
    ltitle = "";
    for (i = 6; i <= NF; i++) {
	if ($i == "[")
	    brackets++;
	else if ($i == "]")
	    if (brackets > 0)
		brackets--;
	    else
		print FILENAME " (line " FNR "): WARNING: unbalanced ']' in title field of %map" >"/dev/stderr";
	else if (ltitle == "")
	    ltitle = $i;
	else
	    ltitle = ltitle " " $i;
    }
    if (brackets > 0)
	print FILENAME " (line " FNR "): WARNING: unbalanced '[' in title field of %map" >"/dev/stderr";
    if (titlelist[name] != "")
	print FILENAME " (line " FNR "): WARNING: several occurrences of '" name "' in sitemap" >"/dev/stderr";
    titlelist[name] = ltitle;
    if (pred == "-") {
	if (output != 0)
	    print FILENAME " (line " FNR "): WARNING: \"-\" used as predecessor while handling regular pages" >"/dev/stderr";
	outer = site;
	if (thislang == lang || altlang[name] == "") {
	    menu = menu "  <DT>" Astart noindex(name) Atitle ltitle Amid stitle Aend "\n";
	    lastup = "  <DT>" Astart gensub(/\/[^\/]*$/, "/" sitemap, "g", name) Atitle uppertitle[lang] Amid upper[lang] Aend "\n";
	}
    }
    else {
	if (output == 0) {
	    output = 1;
	    print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01//EN\"";
	    print "               \"http://www.w3.org/TR/html4/strict.dtd\">";
	    print "<HTML lang=\"" lang Amid;
	    print "<HEAD>";
	    print "  <META http-equiv=\"Content-Type\" content=\"text/html; charset=" encoding "\">";
	    print "  <LINK href=\"" outer css "\" rel=\"stylesheet\" type=\"text/css\">";
	    print "  <LINK href=\"" outer favicon "\" rel=\"shortcut icon\" type=\"image/x-icon\">";
	    print "  <LINK href=\"" home start "\" rel=\"Start\" type=\"text/html\">";
	    print "  <LINK href=\"" othersitemap "\" rel=\"alternate\" lang=\"" otherlang[lang] "\" type=\"text/html\">";
	    print "  <TITLE>Sitemap</TITLE>";
	    print "</HEAD>";
	    print "";
	    print "<BODY id=\"top\">";
	    print "<DIV class=\"logo\">";
	    print Astart site (lang == "en" ? altlang["index"] : "") Atitle hometitle[lang] Amid;
	    print "  <IMG class=\"logo\" alt=\"Computer Languages\" src=\"" outer "logo\">";
	    print Aend;
	    print "</DIV>";
	    print "";
	    print "<DIV>";
	    if (statement != "") {
		print "<P class=\"rightquote\">";
		print statement;
		print "</P>";
	    }
	    print "<H1>Sitemap</H1>";
	    if (lang == "de") {
		print "Die unter " home " erreichbaren hier aufgelisteten";
		print "Web-Seiten werden von " responsible " betreut.";
		print "Aktuelle Ausschnitte folgender Hierarchie scheinen meist im linken Men&uuml; auf:"
	    }
	    else {
		print "The web pages under " home;
		print "listed below were designed and are maintained by ";
		print responsible ".";
		print "The menue at the left hand side usually shows relevant parts of this hierarchy:"
	    }
	    print "<P>";
	}
	if (pred == 0) {
	    if (thislevel != 0)
		print FILENAME " (line " FNR "): WARNING: level-0-page preceded by non-level-0-page" >"/dev/stderr";
	    l = 0;
	    if (thislang == lang || altlang[name] == "")
		menu = menu "  <DT>" Astart noindex(name) Atitle ltitle Amid stitle Aend "\n";
	}
	else if (level[pred] == "") {
	    print FILENAME " (line " FNR "): WARNING: unknown predecessor page \"" pred "\"" >"/dev/stderr";
	    l = 0;
	}
	else {
	    l = level[pred] + 1;
	    if (predstack[l - 1, thislang] != pred)
		print FILENAME " (line " FNR "): WARNING: page belongs to other group than previous page" >"/dev/stderr";
	}
	predstack[l, thislang] = name;
	predstack[l, otherlang[thislang]] = (altlang[name] != "" ? altlang[name] : name);
	level[name] = l;
	if (l > thislevel) {
	    if (l - thislevel > 1)
		print FILENAME " (line " FNR "): WARNING: jump over several levels" >"/dev/stderr";
	    if (thislevel == 0)
		print "<UL>";
	    else
		print indent[thislevel] "  <UL>";
	    thislevel = l;
	}
	else
	    while (l < thislevel) {
		thislevel--;
		print indent[thislevel] "  </UL>";
	    }
	if (thislang == lang || altlang[name] == "") {
	    comment = "";
	    if (name == start) {
		if (comment != "")
		    comment = comment ", ";
		comment = comment startt[thislang];
	    }
	    if (altlang[name] != "") {
		if (comment != "")
		    comment = comment ", ";
		comment = comment Astart noindex(altlang[name]) Atitle alang2[thislang] " Version" Amid alang[thislang] Aend;
	    }
	    else if (thislang != lang) {
		if (comment != "")
		    comment = comment ", ";
		comment = comment sorry[thislang];
	    }
	    if (substr(name, length(name)) == "/") {
		if (system("test -d " name) != 0)
		    print FILENAME " (line " FNR "): WARNING: \"" name "\" does not exist or is no directory" >"/dev/stderr";
	    }
	    else {
		if (system("test -r " name ".gen") != 0)
		    print FILENAME " (line " FNR "): WARNING: \"" name ".gen\" does not exist or is not readable" >"/dev/stderr";
	    }
	    str = Astart noindex(name) Atitle ltitle Amid stitle Aend;
	    if (thislevel > 0)
		str = indent[thislevel] "<LI>" str;
	    if (comment != "")
		str = str  " (" comment ")";
	    print str;
	}
	else
	    langcare = 1;
    }
    next;
}
($1 == "%nomap") {
    if (NF < 2)
	print FILENAME " (line " FNR "): WARNING: %nomap has no argument" >"/dev/stderr";
    name = $2;
    if (titlelist[name] != "")
	print FILENAME " (line " FNR "): WARNING: several occurrences of '" name "' in sitemap" >"/dev/stderr";
    titlelist[name] = "-";
    comment = "";
    cmnt = "";
    lng = lang;
    if (NF > 2) {
	if ($3 != "-") {
	    lng = $3;
	    if (lng != "de" && lng != "en")
	        print FILENAME " (line " FNR "): WARNING: 2nd argument of %nomap differs from de, en, and -" >"/dev/stderr";
	    if (lng == lang && altlang[name] != "")
	        comment = Astart noindex(altlang[name]) Atitle alang2[lang] " Version" Amid alang[lang] Aend;
	    else if (lng != lang && altlang[name] == "")
	        comment = sorry[lng];
	}
	if (comment != "")
	    comment = " (" comment ")";
	if (NF > 3)
	    cmnt = $NF;
	for (i = NF - 1; i > 3; i--)
	    cmnt = $i " " cmnt;
    }
    if (thislevel >= 0) {
	while (thislevel > 1) {
	    thislevel--;
	    print indent[thislevel] "  </UL>";
	}
	if (thislevel > 0)
	    print "</UL>";
	print "<P>";
	print further[lang];
	print "<P>";
	print "<UL>";
	thislevel = -1;
    }
    if (lng == lang || altlang[name] == "")
	if (cmnt == "")
	    print "  <LI>" Astart name Amid name Aend comment;
	else
	    print "  <LI>" Astart name Amid cmnt Aend comment;
    next;
}
END {
    while (thislevel > 1) {
	thislevel--;
	print indent[thislevel] "  </UL>";
    }
    if (thislevel != 0)
	print "</UL>";
    print "";
    print preferences[lang];
    print "</DIV>";
    print "";
    print "<DIV class=\"leftmenu\">";
    print "<DL class=\"leftbuttons\">";
    print menu "</DL>";
    print "</DIV>";
    print "";
    print "<DIV class=\"rightmenu\">";
    print "<DL class=\"rightbuttons\">";
    if (langcare != 0 && othersitemap != "")
	print "  <DT>" Astart noindex(othersitemap) Atitle "This Page in " alang2[lang] Amid alang2[lang] Aend;
    print "  <DT><STRONG title=\"" thispage[lang] "\">Sitemap</STRONG>";
    print lastup "</DL>";
    print "</DIV>";
    print "";
    print "<DIV class=\"fi\">";
    print "<A href=\"" fisite[lang] Atitle fititle[lang] "\">";
    print "  <IMG class=\"fi\" alt=\"" fititle[lang] "\" src=\"" outer "fi\">";
    print Aend;
    print "</DIV>";
    print "";
    print "<DIV class=\"tu\">";
    print "<A href=\"http://www.tuwien.ac.at/" (lang == "en" ? "tuwien_home/EN/" : "") Atitle tutitle[lang] Amid;
    print "  <IMG class=\"tu\" alt=\"" tutitle[lang] "\" src=\"" outer "tu\">";
    print Aend;
    print "</DIV>";
    print "";
    print "<ADDRESS>";
    print addr[lang];
    print "</ADDRESS>";
    print "</BODY>";
    print "</HTML>";
}